Language Reference

Lines and Source Formats

A line is a horizontal arrangement of characters. By contrast, a column is a vertical arrangement of characters, where each character, or each byte of a multibyte character, in a given column shares the same line position.

Because XL Fortran measures lines in bytes, these definitions apply only to lines containing single-byte characters. Each byte of a multibyte character occupies one column.

The kinds of lines are:

Initial Line	Is the first line of a statement.
Continuation Line	Continues a statement beyond its initial line.
Comment Line	Does not affect the executable program and can be used for documentation. The comment text continues to the end of a line. Although comment lines can follow one another, a comment line cannot be continued. A line of all white space or a zero-length line is a comment line without any text. Comment text can contain any characters allowed in a character context. If an initial line or continuation line is not continued, or if it is continued but not in a character context, an inline comment can be placed on the same line, to the right of any statement label, statement text, and continuation character that may be present. An exclamation mark (!) begins an inline comment.
Debug Line	Indicates that the line is for debugging code (for fixed source form only). The letter D must be specified in column 1. (See Debug Lines)
Directive Line	Provides instructions or information to the compiler (see 11.0 , Directives).

Source lines can be in fixed source form or free source form format. Use the SOURCEFORM directive to mix source formats within the same program unit. Fixed source form is the default when using the f77, xlf, xlf_r or xlf_r7 invocation commands. Fortran 90 free source form is the default when using the xlf90, xlf90_r, xlf90_r7, xlf95, xlf95_r or xlf95_r7 invocation commands.

See "Compiling an XL Fortran Program" in the User's Guide for details on invocation commands.

Fixed Source Form

A fixed source form line is a sequence of 1 to 132 characters. The default line size (as stipulated in Fortran 95) is 72 characters, but can be changed using the -qfixed=right_margin compiler option (see the User's Guide).

Columns beyond the right margin are not part of the line and can be used for identification, sequencing, or any other purpose.

Except within a character context, white space is insignificant; that is, you can imbed white space between and within lexical tokens, without affecting the way the compiler will treat them.

Tab formatting means there is a tab character in columns 1 through 6 of an initial line, which directs the compiler to interpret the next character as being in column 7.

Requirements for lines and for items on those lines are:

• A comment line begins with a C, c, or an asterisk (*) in column 1, or is all white space. Comments can also follow an exclamation mark (!), except when the exclamation mark is in column 6 or in a character context.

• For an initial line without tab formatting:
  • Columns 1 through 5 contain either blanks, a statement label, or a D in column 1 optionally followed by a statement label.
  • Column 6 contains a blank or zero.
  • Columns 7 through to the right margin contain statement text, possibly followed by other statements or by an inline comment.

• For an initial line with tab formatting:
  • Columns 1 through 6 begin with either blanks, a statement label, or a D in column 1 optionally followed by a statement label. This must be followed by a tab character.
  • If the -qxflag=oldtab compiler option is specified, all columns from the column immediately following the tab character through to the right margin contain statement text, possibly followed by other statements and by an inline comment.
  • If the -qxflag=oldtab compiler option is not specified, all columns from column 7 (which corresponds to the character after the tab) to the right margin contain statement text, possibly followed by other statements and by an inline comment.

• For a continuation line:
  • Column 1 must not contain C, c, or an asterisk. Columns 1 through 5 must not contain an exclamation mark as the leftmost nonblank character.

    Column 1 can contain a D (signifying a debug line). Otherwise, these columns can contain any characters allowed in a character context; these characters are ignored.

  • Column 6 must have either a nonzero character or white space. The character in column 6 is referred to as the continuation character. Exclamation marks and semicolons are valid continuation characters.
  • Columns 7 through to the right margin contain continued statement text, possibly followed by other statements and an inline comment.
  • Neither the END statement nor a statement whose initial line appears to be a program unit END statement can be continued.
  • There is no limit to the number of continuation lines for a statement, but a statement cannot be longer than 6700 characters.

    The Fortran standards limit the number of continuation lines to 19.

A semicolon (;) separates statements on a single source line, except when it appears in a character context, in a comment, or in columns 1 through 6. Two or more semicolon separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Statements following a semicolon on the same line cannot be labeled. Additional statements cannot follow a program unit END statement on the same line.

Debug Lines

A debug line, allowed only for fixed source form, contains source code used for debugging and is specified by the letter D in column 1. The handling of debug lines depends on the -qdlines compiler option:

• If you specify the -qdlines option, the compiler interprets the D in column 1 as a blank, and handles such lines as lines of source code.

• If you do not specify -qdlines, the compiler handles such lines as comment lines. This is the default setting.

If you continue a debugging statement on more than one line, every continuation line must have a D in column 1 and a continuation character. If the initial line is not a debugging line, you can designate any continuation lines as debug lines provided that the statement is syntactically correct, whether or not you specify the -qdlines option.

Example of Fixed Source Form

C Column Numbers:
C        1         2         3         4         5         6         7
C23456789012345678901234567890123456789012345678901234567890123456789012
 
!IBM* SOURCEFORM (FIXED)
      CHARACTER ABC ; LOGICAL X          ! 2 statements on 1 line
      DO 10 I=1,10
        PRINT *,'this is the index',I  ! with an inline comment
10    CONTINUE
C
       CHARSTR="THIS IS A CONTINUED
     X CHARACTER STRING"
       ! There will be 38 blanks in the string between "CONTINUED"
       ! and "CHARACTER". You cannot have an inline comment on
       ! the initial line because it would be interpreted as part
       ! of CHARSTR (character context).
  100 PRINT *, IERROR
! The following debug lines are compiled as source lines if
! you use -qdlines
D     IF (I.EQ.IDEBUG.AND.
D    +    J.EQ.IDEBUG)     WRITE(6,*) IERROR
D     IF (I.EQ.
D    +  IDEBUG )
D    +  WRITE(6,*) INFO
       END

Free Source Form

XL Fortran allows any line length and number of continuation lines, so long as the number of characters does not exceed 6700.

A free source form line can specify up to 132 characters on each line, with a maximum of 39 continuation lines for a statement.

Items can begin in any column of a line, subject to the following requirements for lines and items on those lines:

• A comment line is a line of white space or begins with an exclamation mark (!) that is not in a character context.

• An initial line can contain any of the following items, in the following sequence:
  • A statement label
  • Statement text
  • Additional statements
  • The ampersand continuation character (&)
  • An inline comment

• A continuation line in a noncharacter context begins on the next noncomment line. If the first nonblank character is an ampersand, the statement continues at the next character position. Otherwise, it continues with the first position of the line.

• A character context can be continued in either of the following cases:
  • The last character of the continued line is an ampersand and is not followed by an inline comment. If the rightmost character of the statement text to be continued is an ampersand, a second ampersand must be entered as a continuation character.
  • The first nonblank character of the next noncomment line is an ampersand.

• If a lexical token is continued, the ampersand must immediately follow the initial part of the token, and the remainder of the token must immediately start after the ampersand on the continuation line.

A semicolon separates statements on a single source line, except when it appears in a character context or in a comment. Two or more separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Additional statements cannot follow a program unit END statement on the same line.

White Space

White space must not appear within lexical tokens, except in a character context or in a format specification. White space can be inserted freely between tokens to improve readability, although it must separate names, constants, and labels from adjacent keywords, names, constants, and labels.

Certain adjacent keywords may require white space. Table 2 lists keywords that require white space, and keywords for which white space is optional.

Table 2. Keywords Where White Space is Optional

White Space Optional
BLOCK DATA DOUBLE COMPLEX DOUBLE PRECISION ELSE IF END BLOCK DATA END DO END FILE END FORALL END FUNCTION END IF END INTERFACE END MODULE END PROGRAM END SELECT END SUBROUTINE END TYPE END WHERE GO TO IN OUT SELECT CASE

See Type Declaration for details about type_spec.

Example of Free Source Form

!IBM* SOURCEFORM (FREE(F90))
!
! Column Numbers:
!        1         2         3         4         5         6         7
!23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,20
   PRINT *,'this statement&
   & is continued' ; IF (I.LT.5) PRINT *, I
 
 ENDDO
 EN&
         &D              ! A lexical token can be continued

IBM Free Source Form

An IBM free source form line or statement is a sequence of up to 6700 characters. Items can begin in any column of a line, subject to the following requirements for lines and items on those lines:

• A comment line begins with a double quotation mark (") in column 1, is a line of all white space, or is a zero-length line. A comment line must not follow a continued line. Comments can also follow an exclamation mark (!), except in a character context.

• An initial line can contain any of the following items, in the following sequence:
  • A statement label
  • Statement text
  • The minus sign continuation character (-)
  • An inline comment

• A continuation line immediately follows a continued line and can contain any of the following items, in the following sequence:
  • Statement text
  • A continuation character (-)
  • An inline comment

If statement text on an initial line or continuation line is to be continued, a minus sign indicates continuation of the statement text on the next line. In a character context, if the rightmost character of the statement text to be continued is a minus sign, a second minus sign must be entered as a continuation character.

Except within a character context, white space is insignificant; that is, you can imbed white space between and within lexical tokens, without affecting the way the compiler will treat them.

Example of IBM Free Source Form

!IBM* SOURCEFORM (FREE(IBM))
"
" Column Numbers:
"        1         2         3         4         5         6         7
"23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,10
  PRINT *,'this is -
             the index',I   ! There will be 14 blanks in the string
                            ! between "is" and "the"
 END DO
 END